Function: org-babel-lilypond-process-basic

org-babel-lilypond-process-basic is a byte-compiled function defined in ob-lilypond.el.gz.

Signature

(org-babel-lilypond-process-basic BODY PARAMS)

Documentation

Execute a lilypond block in basic mode.

See org-babel-execute-src-block for BODY and PARAMS.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-lilypond.el.gz
(defun org-babel-lilypond-process-basic (body params)
  "Execute a lilypond block in basic mode.
See `org-babel-execute-src-block' for BODY and PARAMS."
  (let* ((out-file (cdr (assq :file params)))
         (file-type (file-name-extension out-file))
	 (cmdline (or (cdr (assq :cmdline params))
		      ""))
	 (in-file (org-babel-temp-file "lilypond-")))

    (with-temp-file in-file
      (insert
       (format org-babel-lilypond-paper-settings file-type)
       (org-babel-expand-body:generic body params)))
    (org-babel-eval
     (concat
      org-babel-lilypond-ly-command
      " -dbackend=eps "
      "-dno-gs-load-fonts "
      "-dinclude-eps-fonts "
      (or (assoc-default file-type
                         '(("pdf" . "--pdf ")
			   ("eps" . "--eps ")))
	  "--png ")
      "--output="
      (file-name-sans-extension out-file)
      " "
      cmdline
      in-file)
     ""))
  nil)