Function: org-babel-tangle--unbracketed-link

org-babel-tangle--unbracketed-link is a byte-compiled function defined in ob-tangle.el.gz.

Signature

(org-babel-tangle--unbracketed-link PARAMS)

Documentation

Get a raw link to the src block at point, without brackets.

The PARAMS are the 3rd element of the info for the same src block.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-tangle.el.gz
(defun org-babel-tangle--unbracketed-link (params)
  "Get a raw link to the src block at point, without brackets.

The PARAMS are the 3rd element of the info for the same src block."
  (unless (string= "no" (cdr (assq :comments params)))
    (save-match-data
      (let* ((l (org-no-properties (org-store-link nil)))
             (bare (and l
                        (string-match org-link-bracket-re l)
                        (match-string 1 l))))
        (when bare
          (if (and org-babel-tangle-use-relative-file-links
                   (string-match org-link-types-re bare)
                   (string= (match-string 1 bare) "file"))
              (concat "file:"
                      (file-relative-name (substring bare (match-end 0))
                                          (file-name-directory
                                           (cdr (assq :tangle params)))))
            bare))))))