Function: org-link-preview--process-queue

org-link-preview--process-queue is a byte-compiled function defined in ol.el.gz.

Signature

(org-link-preview--process-queue ORG-BUFFER)

Documentation

Preview pending Org link previews in ORG-BUFFER.

Previews are generated from the specs in org-link-preview--queue, which see.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ol.el.gz
(defun org-link-preview--process-queue (org-buffer)
  "Preview pending Org link previews in ORG-BUFFER.

Previews are generated from the specs in
`org-link-preview--queue', which see."
  (and (buffer-live-p org-buffer)
       (with-current-buffer org-buffer
         (cl-loop
          for spec in org-link-preview--queue
          for ov = (cadr spec)    ;SPEC is (preview-func ov path link)
          for count from org-link-preview-batch-size above 0
          do (pop org-link-preview--queue)
          if (overlay-buffer ov) do
          (if (apply spec)
              (overlay-put ov 'org-image-overlay t)
            ;; Preview was unsuccessful, delete overlay
            (delete-overlay ov)
            (setq org-link-preview-overlays
                  (delq ov org-link-preview-overlays)))
          else do (cl-incf count) end
          finally do
          (setq org-link-preview--timer
                (and org-link-preview--queue
                     (run-with-idle-timer
                      (time-add (or (current-idle-time) 0)
                                org-link-preview-delay)
                      nil #'org-link-preview--process-queue org-buffer)))))))