Function: org-man-item

org-man-item is a byte-compiled function defined in ox-man.el.gz.

Signature

(org-man-item ITEM CONTENTS INFO)

Documentation

Transcode an ITEM element from Org to Man.

CONTENTS holds the contents of the item. INFO is a plist holding contextual information.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ox-man.el.gz
;;; Item


(defun org-man-item (item contents info)
  "Transcode an ITEM element from Org to Man.
CONTENTS holds the contents of the item.  INFO is a plist holding
contextual information."
  (let* ((bullet (org-element-property :bullet item))
         (type (org-element-property :type (org-element-parent item)))
         (checkbox (pcase (org-element-property :checkbox item)
                     (`on "\\o'\\(sq\\(mu'")
                     (`off "\\(sq ")
                     (`trans "\\o'\\(sq\\(mi'")))

         (tag (let ((tag (org-element-property :tag item)))
                ;; Check-boxes must belong to the tag.
                (and tag (format "\\fB%s\\fP"
                                 (concat checkbox
                                         (org-export-data tag info)))))))

    (if (and (null tag) (null checkbox))
	(let* ((bullet (org-trim bullet))
	       (marker (cond  ((string= "-" bullet) "\\(em")
			      ((string= "*" bullet) "\\(bu")
			      ((eq type 'ordered)
			       (format "%s " (org-trim bullet)))
			      (t "\\(dg"))))
	  (concat ".IP " marker " 4\n"
		  (org-trim (or contents " " ))))
      (concat ".TP\n" (or tag (concat " " checkbox)) "\n"
              (org-trim (or contents " " ))))))