Function: package-menu--print-info-simple

package-menu--print-info-simple is a byte-compiled function defined in package.el.gz.

Signature

(package-menu--print-info-simple PKG)

Documentation

Return a package entry suitable for tabulated-list-entries.

PKG is a package-desc object. Return (PKG-DESC [NAME VERSION STATUS DOC]).

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/package.el.gz
(defun package-menu--print-info-simple (pkg)
  "Return a package entry suitable for `tabulated-list-entries'.
PKG is a `package-desc' object.
Return (PKG-DESC [NAME VERSION STATUS DOC])."
  (let* ((status  (package-desc-status pkg))
         (face (alist-get status package-menu-status-faces
                          nil nil #'string=)))
    (list pkg
          `[(,(symbol-name (package-desc-name pkg))
             face package-name
             font-lock-face package-name
             follow-link t
             package-desc ,pkg
             action package-menu-describe-package)
            ,(propertize
              (if (package-vc-p pkg)
                  (progn
                    (require 'package-vc)
                    (package-vc-commit pkg))
                (package-version-join
                 (package-desc-version pkg)))
              'font-lock-face face)
            ,(propertize status 'font-lock-face face)
            ,(propertize (or (package-desc-archive pkg) "")
                                    'font-lock-face face)
            ,(propertize (package-desc-summary pkg)
                         'font-lock-face 'package-description)])))