Function: projectile-consult-find-file

projectile-consult-find-file is an autoloaded, interactive and byte-compiled function defined in projectile-consult.el.

Signature

(projectile-consult-find-file)

Documentation

Find a file in the current project with a streaming Consult UI.

The candidate list is produced by Projectile's own indexing command (see projectile-project-files-producer), so it honours the project's VCS and indexing configuration, and it streams into the minibuffer as the command runs instead of blocking until the whole project is indexed.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/projectile-20260930.434/projectile-consult.el
;;;###autoload
(defun projectile-consult-find-file ()
  "Find a file in the current project with a streaming Consult UI.

The candidate list is produced by Projectile's own indexing command (see
`projectile-project-files-producer'), so it honours the project's VCS and
indexing configuration, and it streams into the minibuffer as the command
runs instead of blocking until the whole project is indexed."
  (interactive)
  (require 'consult)
  (let* ((producer (projectile-project-files-producer))
         (root (plist-get producer :directory))
         (command (plist-get producer :command)))
    (unless command
      (user-error "External-command indexing is disabled for this project"))
    (let* ((default-directory root)
           (selected
            (consult--read
             (consult--process-collection (projectile-consult--builder command)
               ;; List immediately, with no input required.
               :min-input 0
               ;; Match Projectile's own `./'-stripping.
               :transform (consult--async-map
                           (lambda (path) (string-remove-prefix "./" path)))
               ;; Route the process through TRAMP for remote projects.
               :file-handler t)
             :prompt (format "Find file in %s: " (projectile-project-name))
             :sort nil
             :require-match t
             :category 'file
             :history '(:input projectile-consult-find-file-history))))
      (find-file (expand-file-name selected root)))))