Function: talk-split-up-frame

talk-split-up-frame is a byte-compiled function defined in talk.el.gz.

Signature

(talk-split-up-frame FRAME BUFFERS)

Documentation

Split FRAME into equal-sized windows displaying the buffers in BUFFERS.

Select the first of these windows, displaying the first of the buffers.

Source Code

;; Defined in /usr/src/emacs/lisp/talk.el.gz
(defun talk-split-up-frame (frame buffers)
  "Split FRAME into equal-sized windows displaying the buffers in BUFFERS.
Select the first of these windows, displaying the first of the buffers."
  (let ((lines-per-buffer (/ (frame-height frame) (length buffers)))
	(old-frame (selected-frame)))
    (unwind-protect
	(progn
	  (select-frame frame)
	  (select-window (frame-first-window frame))
	  (delete-other-windows)
	  (while (progn
		   (switch-to-buffer (car buffers))
		   (setq buffers (cdr buffers)))
	    (split-window-below lines-per-buffer)
	    (other-window 1))
	  (select-window (frame-first-window frame)))
      (select-frame old-frame))))