Function: tty-tip--create-frame

tty-tip--create-frame is a byte-compiled function defined in tty-tip.el.gz.

Signature

(tty-tip--create-frame TEXT)

Source Code

;; Defined in /usr/src/emacs/lisp/tty-tip.el.gz
(defun tty-tip--create-frame (text)
  (let* ((minibuffer (minibuffer-window (window-frame)))
         (buffer (tty-tip--make-buffer text))
         (window-min-height 1)
         (window-min-width 1)
         after-make-frame-functions
	 (text-lines (string-lines text)))
    (setq tty-tip--frame
          (make-frame
           `((parent-frame . ,(car (mouse-position)))
             (minibuffer . ,minibuffer)
             ,@(tty-tip--frame-parameters))))
    (let ((win (frame-root-window tty-tip--frame)))
      (set-window-buffer win buffer)
      (set-window-dedicated-p win t)
      (set-frame-size tty-tip--frame
                      (apply #'max (mapcar #'string-width text-lines))
                      (length text-lines))
      (let* ((pos (tty-tip--compute-position))
             (x (car pos))
             (y (cdr pos)))
	(set-frame-position tty-tip--frame x y))
      (make-frame-visible tty-tip--frame)
      (setq tty-tip--hide-timer
            (run-with-timer tooltip-hide-delay nil
                            #'tty-tip--delete-frame)))))