Function: use-package-normalize/:delight

use-package-normalize/:delight is an autoloaded and byte-compiled function defined in use-package-delight.el.gz.

Signature

(use-package-normalize/:delight NAME KEYWORD ARGS)

Documentation

Normalize arguments to delight.

Source Code

;; Defined in /usr/src/emacs/lisp/use-package/use-package-delight.el.gz
;;;###autoload
(defun use-package-normalize/:delight (name _keyword args)
  "Normalize arguments to delight."
  (cond ((null args)
         `((,(use-package-as-mode name) nil ,name)))
        ((and (= (length args) 1)
              (use-package-non-nil-symbolp (car args)))
         `((,(car args) nil ,name)))
        ((and (= (length args) 1)
              (stringp (car args)))
         `((,(use-package-as-mode name) ,(car args) ,name)))
        ((and (= (length args) 1)
              (listp (car args))
              (eq 'quote (caar args)))
         `((,(use-package-as-mode name) ,@(cdar args) ,name)))
        ((and (= (length args) 2)
              (listp (nth 1 args))
              (eq 'quote (car (nth 1 args))))
         `((,(car args) ,@(cdr (nth 1 args)) ,name)))
        (t (mapcar
            (apply-partially #'use-package-normalize-delight name)
            (if (use-package-non-nil-symbolp (car args))
                (list args)
              args)))))