Variable: elide-head-headers-to-hide

elide-head-headers-to-hide is a customizable variable defined in elide-head.el.gz.

Value

(("is free software[:;] you can redistribute it"
  . "\\(?:If not, see <?https?://www\\.gnu\\.org/licenses/?>? ?\\|Boston,\\(?: +\\|[	 ]*\n[	 ]*\\(?:\\s<\\|[#*;-]\\)*[	 ]*\\)MA\\(?: +\\|[	 ]*\n[	 ]*\\(?:\\s<\\|[#*;-]\\)*[	 ]*\\)\\(?:021\\(?:1\\(?:0-1301\\|1-130[17]\\)\\|96\\)\\),?\\(?: +\\|[	 ]*\n[	 ]*\\(?:\\s<\\|[#*;-]\\)*[	 ]*\\)USA\\|675 Mass Ave, Cambridge, MA 02139, USA\\)\\.?")
 ("\\(?:Redistribution and use in source and binary\\|The Regents of the University of California\\.  All rights reserved\\.\\)"
  . "POSSIBILITY OF SUCH DAMAGE\\.")
 ("Permission is hereby granted, free of charge"
  . "\\(?:\\(?:THE USE OR OTHER DEALINGS IN THE SOFTWARE\\|authorization from the X Consortium\\)\\.\\)")
 ("Licensed under the Apache License, Version 2.0"
  . "limitations under the License."))

Documentation

Alist of regexps defining start and end of text to elide.

The cars of elements of the list are searched for in order. Text is elided with an invisible overlay from the end of the line where the first match is found to the end of the match for the corresponding cdr.

This affects elide-head-mode(var)/elide-head-mode(fun).

This variable was added, or its default value changed, in Emacs 30.1.

Source Code

;; Defined in /usr/src/emacs/lisp/elide-head.el.gz
(defcustom elide-head-headers-to-hide
  (rx-let ((delim
            ;; A line break could be in a non-standard place, and the
            ;; license could be in a comment.
            (or
             ;; Either just some spaces:
             (+ " ")
             ;; Or a newline and some comment starter:
             (: (* (in " \t"))
                "\n"
                (* (in " \t"))
                (* (or (syntax comment-start) (in ";#*-")))
                (* (in " \t"))))))
    `(;; GNU GPL
      ("is free software[:;] you can redistribute it" .
       ,(rx (or (seq "If not, see " (? "<")
                     "http" (? "s") "://www.gnu.org/licenses"
                     (? "/") (? ">") (? " "))
                (seq "Boston," delim "MA" delim
                     (or "02111-1307" "02110-1301" "02111-1301" "02196")
                     (? ",") delim
                     "USA")
                "675 Mass Ave, Cambridge, MA 02139, USA")
            (? ".")))
      ;; FreeBSD license / Modified BSD license (3-clause)
      (,(rx (or "The Regents of the University of California.  All rights reserved."
                "Redistribution and use in source and binary"))
       . "POSSIBILITY OF SUCH DAMAGE\\.")
      ;; X11 and Expat
      ("Permission is hereby granted, free of charge" .
       ,(rx (or "authorization from the X Consortium."          ; X11
                "THE USE OR OTHER DEALINGS IN THE SOFTWARE."))) ; Expat
      ;; Apache
      ("Licensed under the Apache License, Version 2.0" .
       "limitations under the License.")
      ))
  "Alist of regexps defining start and end of text to elide.

The cars of elements of the list are searched for in order.  Text is
elided with an invisible overlay from the end of the line where the
first match is found to the end of the match for the corresponding
cdr.

This affects `elide-head-mode'."
  :type '(alist :key-type  (regexp :tag "Start regexp")
                :value-type (regexp :tag "End regexp"))
  :version "30.1")