Variable: sgml-quick-keys

sgml-quick-keys is a customizable variable defined in sgml-mode.el.gz.

Value

nil

Documentation

Use <, >, &, /, SPC and sgml-specials keys "electrically" when non-nil.

By setting the option to indent, Emacs will eagerly reindent the current line when you manually close a tag.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/sgml-mode.el.gz
(defcustom sgml-quick-keys nil
  "Use <, >, &, /, SPC and `sgml-specials' keys \"electrically\" when non-nil.
By setting the option to `indent', Emacs will eagerly reindent the
current line when you manually close a tag."
  :set (lambda (sym val)
         (set-default sym val)
         (dolist (bind `(("&"  . ,#'sgml-name-char)
                         ("<"  . ,#'sgml-tag)
                         ("\s" . ,#'sgml-auto-attributes)
                         (">"  . ,#'sgml-maybe-end-tag)
                         ("\"" . ,(and (memq ?\" sgml-specials) #'sgml-name-self))
                         ("'"  . ,(and (memq ?' sgml-specials) #'sgml-name-self))))
           (if (and val (cdr bind))
               (define-key sgml-mode-map (car bind) (cdr bind))
             (define-key sgml-mode-map (car bind) nil t)))
         (custom-reevaluate-setting 'html-quick-keys))
  :type '(choice (const :tag "Enabled" t)
                 (const :tag "Enabled, and indent when closing tags" indent)
                 ;; Omit `close' because `electric-pair-mode' already
                 ;; takes care of paring "<" and ">".
                 (const :tag "Disabled" nil)))