Function: IT-setup-unicode-display

IT-setup-unicode-display is an interactive and byte-compiled function defined in internal.el.gz.

Signature

(IT-setup-unicode-display CODING &optional TABLE)

Documentation

Set up display table TABLE for displaying mule-unicode-* characters on a DOS terminal whose codepage provides the coding-system CODING. If TABLE is nil or omitted, standard-display-table is used.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/term/internal.el.gz
(defun IT-setup-unicode-display (coding &optional table)
  "Set up display table TABLE for displaying mule-unicode-* characters
on a DOS terminal whose codepage provides the coding-system CODING.
If TABLE is nil or omitted, `standard-display-table' is used."
  (interactive "zCode page: ")
  (let ((disp-tab (or table standard-display-table))
	(tail IT-unicode-translations)
	translation)
    (while tail
      (setq translation (car tail) tail (cdr tail))
      (let* ((first (car translation))
	     (last (nth 1 translation))
	     (table (nth 2 translation))
	     (i 0)
	     (this first)
	     glyph)
	(while (<= i (- last first))
	  (setq glyph (aref table i))
	  (when (and glyph
		     (unencodable-char-position 0 1 coding nil (string this)))
	    (aset disp-tab this
		  (vconcat (if (numberp glyph)
			       (string glyph)
			     glyph))))
	  (setq i (1+ i) this (1+ this)))))))