Function: Info-prev-reference

Info-prev-reference is an interactive and byte-compiled function defined in info.el.gz.

Signature

(Info-prev-reference &optional RECUR COUNT)

Documentation

Move cursor to the previous cross-reference or menu item in the node.

If COUNT is non-nil (interactively with a prefix arg), jump over COUNT cross-references.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/info.el.gz
(defun Info-prev-reference (&optional recur count)
  "Move cursor to the previous cross-reference or menu item in the node.
If COUNT is non-nil (interactively with a prefix arg), jump over
COUNT cross-references."
  (interactive "i\np" Info-mode)
  (unless count
    (setq count 1))
  (if (< count 0)
      (Info-next-reference recur (- count))
    (while (unless (zerop count) (setq count (1- count)))
      (let ((pat "\\*note[ \n\t]+\\([^:]+\\):\\|^\\* .*:\\|[hf]t?tps?://")
	    (old-pt (point))
	    (case-fold-search t))
	(or (Info-prev-reference-or-link pat 'link)
	    (progn
	      (goto-char (point-max))
	      (or (Info-prev-reference-or-link pat 'link)
		  (progn
		    (goto-char old-pt)
		    (user-error "No cross references in this node")))))
	(if (looking-at "\\* Menu:")
	    (if recur
		(user-error "No cross references in this node")
	      (Info-prev-reference t))
	  (if (looking-at "^\\* ")
	      (forward-char 2)))))))