Function: LaTeX-back-to-indentation

LaTeX-back-to-indentation is a byte-compiled function defined in latex.el.

Signature

(LaTeX-back-to-indentation &optional FORCE-TYPE)

Documentation

Move point to the first non-whitespace character on this line.

If it is commented and comments are formatted syntax-aware move point to the first non-whitespace character after the comment character(s), but only if this-command is not a newline command, that is, TeX-newline or the value of TeX-newline-function. The optional argument FORCE-TYPE can be used to force point being moved to the inner or outer indentation in case of a commented line. The symbols inner and outer are recognized.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/latex.el
(defun LaTeX-back-to-indentation (&optional force-type)
  "Move point to the first non-whitespace character on this line.
If it is commented and comments are formatted syntax-aware move
point to the first non-whitespace character after the comment
character(s), but only if `this-command' is not a newline
command, that is, `TeX-newline' or the value of
`TeX-newline-function'.  The optional argument FORCE-TYPE can be
used to force point being moved to the inner or outer indentation
in case of a commented line.  The symbols `inner' and `outer' are
recognized."
  (if (or (and force-type
               (eq force-type 'inner))
          (and (not force-type)
               (or (and (TeX-in-line-comment)
                        (eq major-mode 'docTeX-mode))
                   (and (TeX-in-commented-line)
                        ;; Only move after the % if we're not
                        ;; performing a newline command (bug#47757).
                        (not (memq this-command
                                   `( TeX-newline
                                      ,TeX-newline-function)))
                        LaTeX-syntactic-comments))))
      (progn
        (beginning-of-line)
        ;; Should this be anchored at the start of the line?
        (TeX-re-search-forward-unescaped
         (concat "\\(?:" TeX-comment-start-regexp "+[ \t]*\\)+")
         (line-end-position) t))
    (back-to-indentation)))