Function: Man-bgproc-filter

Man-bgproc-filter is a byte-compiled function defined in man.el.gz.

Signature

(Man-bgproc-filter PROCESS STRING)

Documentation

Manpage background process filter.

When manpage command is run asynchronously, PROCESS is the process object for the manpage command; when manpage command is run synchronously, PROCESS is the name of the buffer where the manpage command is run. Second argument STRING is the entire string of output.

Source Code

;; Defined in /usr/src/emacs/lisp/man.el.gz
(defun Man-bgproc-filter (process string)
  "Manpage background process filter.
When manpage command is run asynchronously, PROCESS is the process
object for the manpage command; when manpage command is run
synchronously, PROCESS is the name of the buffer where the manpage
command is run.  Second argument STRING is the entire string of output."
  (save-excursion
    (let ((Man-buffer (process-buffer process)))
      (if (not (buffer-live-p Man-buffer)) ;; deleted buffer
	  (set-process-buffer process nil)

	(with-current-buffer Man-buffer
	  (let ((inhibit-read-only t)
                (beg (marker-position (process-mark process))))
	    (save-excursion
	      (goto-char beg)
	      (insert string)
	      (save-restriction
		(narrow-to-region
		 (save-excursion
		   (goto-char beg)
                   ;; Process whole sections (Bug#36927).
                   (Man-previous-section 1)
                   (point))
		 (point))
		(man--maybe-fontify-manpage))
	      (set-marker (process-mark process) (point-max)))))))))