Function: TeX-abbrev-mode-setup

TeX-abbrev-mode-setup is a macro defined in tex.el.

Signature

(TeX-abbrev-mode-setup MODE USERTABLE)

Documentation

Set up the abbrev table and variable for MODE.

The table inherits from USERTABLE if it is a valid abbrev table.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
;;; Abbrev mode

(defmacro TeX-abbrev-mode-setup (mode usertable)
  "Set up the abbrev table and variable for MODE.
The table inherits from USERTABLE if it is a valid abbrev table."
  (let ((symbol (intern (concat (symbol-name mode) "-abbrev-table")))
        (name (TeX-mode-prefix mode)))
    `(progn
       (defvar ,symbol nil
         ,(format "Abbrev table for %s mode." name))
       (define-abbrev-table ',symbol nil)
       (let ((parents (list text-mode-abbrev-table)))
         ;; Users may already have user abbrevs in tables based on the
         ;; former mode names such as `latex-mode-abbrev-table',
         ;; stored in .emacs.d/abbrev_defs.  In that case, add them as
         ;; parent abbrev tables.
         (if (and (boundp ',usertable)
                  (abbrev-table-p ,usertable))
             (push ,usertable parents))
         (abbrev-table-put ,symbol :parents parents)))))