Function: TeX-arg-verb-delim-or-brace

TeX-arg-verb-delim-or-brace is a byte-compiled function defined in latex.el.

Signature

(TeX-arg-verb-delim-or-brace OPTIONAL &optional PROMPT)

Documentation

Prompt for delimiter and text.

If OPTIONAL, indicate optional argument in minibuffer. PROMPT is a string replacing the default one when asking the user for text. This function is intended for \verb like macros which take their argument in delimiters like "| |" or braces "{ }".

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/latex.el
(defun TeX-arg-verb-delim-or-brace (optional &optional prompt)
  "Prompt for delimiter and text.
If OPTIONAL, indicate optional argument in minibuffer.  PROMPT is
a string replacing the default one when asking the user for text.
This function is intended for \\verb like macros which take their
argument in delimiters like \"| |\" or braces \"{ }\"."
  (let ((del (read-quoted-char
              (format-prompt "Delimiter" (char-to-string
                                          LaTeX-default-verb-delimiter)))))
    (when (<= del ?\ )
      (setq del LaTeX-default-verb-delimiter))
    (if (TeX-active-mark)
        (progn
          (insert del)
          (goto-char (mark))
          ;; If the delimiter was an opening brace, close it with a
          ;; brace, otherwise use the delimiter again
          (insert (if (= del ?\{)
                      ?\}
                    del)))
      ;; Same thing again
      (insert del (read-from-minibuffer
                   (TeX-argument-prompt optional prompt "Text"))
              (if (= del ?\{)
                  ?\}
                del)))
    ;; Do not set `LaTeX-default-verb-delimiter' if the user input was
    ;; an opening brace.  This would give funny results for the next
    ;; "C-c C-m \verb RET"
    (unless (= del ?\{)
      (setq LaTeX-default-verb-delimiter del))))