Function: TeX-auto-parse

TeX-auto-parse is a byte-compiled function defined in tex.el.

Signature

(TeX-auto-parse)

Documentation

Parse TeX information in current buffer.

Call the functions in TeX-auto-prepare-hook before parsing, and the functions in TeX-auto-cleanup-hook after parsing.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
(defun TeX-auto-parse ()
  "Parse TeX information in current buffer.

Call the functions in `TeX-auto-prepare-hook' before parsing, and the
functions in `TeX-auto-cleanup-hook' after parsing."

  (let ((case-fold-search nil))

    (mapc #'TeX-auto-clear-entry TeX-auto-parser)
    (run-hooks 'TeX-auto-prepare-hook)

    (save-excursion
      (and (> TeX-auto-x-parse-length TeX-auto-parse-length)
           (> (point-max) TeX-auto-parse-length)
           (TeX-auto-parse-region TeX-auto-x-regexp-list
                                  TeX-auto-parse-length
                                  TeX-auto-x-parse-length))
      (TeX-auto-parse-region TeX-auto-regexp-list
                             nil TeX-auto-parse-length))

    ;; Cleanup ignored symbols.

    ;; NOTE: This is O(N M) where it could be O(N log N + M log M) if we
    ;; sorted the lists first.
    (while (member (car TeX-auto-symbol) TeX-auto-ignore)
      (setq TeX-auto-symbol (cdr TeX-auto-symbol)))
    (let ((list TeX-auto-symbol))
      (while (and list (cdr list))
        (if (member (car (cdr list)) TeX-auto-ignore)
            (setcdr list (cdr (cdr list)))
          (setq list (cdr list)))))

    (run-hooks 'TeX-auto-cleanup-hook)))