Function: TeX-inline-preview-internal

TeX-inline-preview-internal is a byte-compiled function defined in preview.el.

Signature

(TeX-inline-preview-internal COMMAND FILE PR-FILE COMMANDBUFF DUMPED-CONS MASTER GEOMETRY &optional STR)

Documentation

Internal stuff for previewing.

COMMAND and FILE should be explained in TeX-command-list. PR-FILE is the target file name in the form for preview-gs-file. COMMANDBUFF, DUMPED-CONS, MASTER, and GEOMETRY are internal parameters, STR may be a log to insert into the current log.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/preview.el
(defun TeX-inline-preview-internal (command file pr-file
                                    commandbuff dumped-cons _master
                                    geometry
                                    &optional str)
  "Internal stuff for previewing.
COMMAND and FILE should be explained in `TeX-command-list'.
PR-FILE is the target file name in the form for `preview-gs-file'.
COMMANDBUFF, DUMPED-CONS, MASTER, and GEOMETRY are
internal parameters, STR may be a log to insert into the current log."
  (set-buffer commandbuff)
  (let*
      ((preview-format-name (shell-quote-argument
                             (concat "&"
                                     (preview-dump-file-name
                                      ;; Get the filename from
                                      ;; `TeX-master-file' with prv to
                                      ;; get the correct path but then
                                      ;; strip the extension
                                      (file-name-sans-extension
                                       (TeX-master-file "prv" t))))))
       (process-environment (copy-sequence process-environment))
       (process
        (progn
          ;; Fix Bug#20773, Bug#27088.
          ;; Make LaTeX not to insert newline in lines necessary to
          ;; identify Bounding Boxes.
          (setenv "max_print_line" "1000")
          (TeX-run-command
           "Preview-LaTeX"
           (if (consp (cdr dumped-cons))
               (preview-do-replacements
                command
                preview-undump-replacements)
             command)
           file))))
    (condition-case err
        (progn
          (when str
            (save-excursion
              (goto-char (point-min))
              (insert str)
              (when (= (process-mark process) (point-min))
                (set-marker (process-mark process) (point)))))
          (preview-set-geometry geometry)
          (setq preview-gs-file pr-file)
          (setq TeX-sentinel-function #'preview-TeX-inline-sentinel)
          (TeX-parse-reset)
          (setq TeX-parse-function #'TeX-parse-TeX)
          (if TeX-process-asynchronous
              process
            (TeX-synchronous-sentinel "Preview-LaTeX" file process)))
      (error (preview-log-error err "Preview" process)
             (delete-process process)
             (preview-reraise-error process)))))