Function: TeX-mode-cleanup

TeX-mode-cleanup is a byte-compiled function defined in tex.el.

Signature

(TeX-mode-cleanup)

Documentation

Cleanup function for TeX-mode.

Run after mode hooks and file local variables application.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
(defun TeX-mode-cleanup ()
  "Cleanup function for `TeX-mode'.
Run after mode hooks and file local variables application."
  ;; Symbol & length completion.
  (or (local-variable-p 'TeX-complete-list)
      (setq-local TeX-complete-list
                  (list (list "\\\\\\([a-zA-Z@:_]*\\)"
                              1
                              (lambda ()
                                (append
                                 (TeX-symbol-list-filtered)
                                 ;; These LaTeX-*-list are called even
                                 ;; in non-LaTeX mode buffers, but
                                 ;; that is permissible because they
                                 ;; return empty list immediately.
                                 (when (fboundp 'LaTeX-length-list)
                                   (LaTeX-length-list))
                                 (when (fboundp 'LaTeX-counter-list)
                                   (mapcar (lambda (x)
                                             `(,(concat "the" (car x))))
                                           (LaTeX-counter-list)))))
                              (if TeX-insert-braces "{}"))
                        (list "" TeX-complete-word))))

  ;; Complete style initialization in buffers which don't visit files
  ;; and which are therefore missed by the setting of above
  ;; `find-file-hook'.  This is necessary for `xref-find-references',
  ;; for example. (bug#65912)
  (unless buffer-file-truename
    (TeX-update-style))

  (TeX-set-mode-name))