Function: TeX-printer-query

TeX-printer-query is a byte-compiled function defined in tex.el.

Signature

(TeX-printer-query &optional QUEUE)

Documentation

Query the user for a printer name.

QUEUE is non-nil when we are checking for the printer queue.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
(defun TeX-printer-query (&optional queue)
  "Query the user for a printer name.
QUEUE is non-nil when we are checking for the printer queue."
  (let (command element printer)
    (if queue
        (unless (setq element 2 command TeX-queue-command)
          (error "Need to customize `TeX-queue-command'"))
      (unless (setq element 1 command TeX-print-command)
        (error "Need to customize `TeX-print-command'")))
    (while (progn
             (setq printer (if TeX-printer-list
                               (let ((completion-ignore-case t))
                                 (completing-read
                                  (format "Printer%s: "
                                          (if TeX-printer-default
                                              (format " (default %s)" TeX-printer-default) ""))
                                  TeX-printer-list))
                             ""))
             (setq printer (or (car-safe (assoc-string printer TeX-printer-list t))
                               printer))
             (not (if (or (null printer) (string-equal "" printer))
                      (setq printer TeX-printer-default)
                    (setq TeX-printer-default printer)))))

    (let ((expansion (let ((entry (assoc printer TeX-printer-list)))
                       (or (nth element entry)
                           command))))
      (if (string-match "%p" printer)
          (error "Don't use %s in printer names" "%p"))
      (while (string-match "%p" expansion)
        (setq expansion (replace-match printer t t expansion 0)))
      expansion)))