Function: TeX-run-command

TeX-run-command is a byte-compiled function defined in tex.el.

Signature

(TeX-run-command NAME COMMAND FILE)

Documentation

Create a process for NAME using COMMAND to process FILE.

Return the new process.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
(defun TeX-run-command (name command file)
  "Create a process for NAME using COMMAND to process FILE.
Return the new process."
  (let ((default TeX-command-default)
        (buffer (TeX-process-buffer-name file))
        (dir (TeX-master-directory))
        (command-buff (current-buffer)))
    (TeX-process-check file)            ; Check that no process is running
    (setq-default TeX-command-buffer command-buff)
    (get-buffer-create buffer)
    (set-buffer buffer)
    (buffer-disable-undo)
    (erase-buffer)
    (setq-local line-number-display-limit 0)
    (setq TeX-output-extension nil)
    (setq-local TeX-command-buffer command-buff)
    (if dir (cd dir))
    (insert "Running `" name "' on `" file "' with ``" command "''\n")
    (TeX-output-mode)
    (if TeX-show-compilation
        (display-buffer buffer)
      (unless TeX-suppress-compilation-message
        (message "Type `%s' to display results of compilation."
                 (substitute-command-keys
                  "\\<TeX-mode-map>\\[TeX-recenter-output-buffer]"))))
    (setq TeX-parse-function #'TeX-parse-command)
    (setq TeX-command-default default)
    (setq TeX-sentinel-function
          (lambda (_process name)
            (message (concat name ": done."))))
    (let ((process-environment (TeX-process-environment)))
      (if TeX-process-asynchronous
          (let ((process (start-process name buffer TeX-shell
                                        TeX-shell-command-option command)))
            (if TeX-after-start-process-function
                (funcall TeX-after-start-process-function process))
            (TeX-command-mode-line process)
            (set-process-filter process #'TeX-command-filter)
            (set-process-sentinel process #'TeX-command-sentinel)
            (set-marker (process-mark process) (point-max))
            (require 'compile)
            (setq compilation-in-progress (cons process compilation-in-progress))
            process)
        (setq mode-line-process ": run")
        (force-mode-line-update)
        (call-process TeX-shell nil buffer nil
                      TeX-shell-command-option command)))))