Function: activities-list

activities-list is an autoloaded, interactive and byte-compiled function defined in activities-list.el.

Signature

(activities-list)

Documentation

List activities.

Key Bindings

Aliases

list-activities

Source Code

;; Defined in ~/.emacs.d/elpa/activities-0.7.2/activities-list.el
;;;###autoload
(defun activities-list ()
  "List activities."
  (interactive)
  (unless activities-activities
    (user-error (substitute-command-keys "No activities defined (to define one, type \"\\[activities-new]\")")))
  (with-current-buffer (get-buffer-create "*Activities*")
    (let ((inhibit-read-only t))
      (read-only-mode)
      (erase-buffer)
      (make-vtable
       :columns
       `(( :name "Active" :primary descend
           :getter (lambda (object _table)
                     (if (activities-activity-active-p object)
                         "*" " ")))
         ( :name "Name"
           :getter (lambda (object _table)
                     (activities-activity-name object)))
         ( :name "Last saved"
           :getter (lambda (activity _table)
                     (pcase-let (((cl-struct activities-activity last) activity))
                       (when last
                         (map-elt (activities-activity-state-etc last) 'time))))
           :formatter activities-list--format-time)
         ( :name "Default saved"
           :getter (lambda (activity _table)
                     (pcase-let (((cl-struct activities-activity default) activity))
                       (when default
                         (map-elt (activities-activity-state-etc default) 'time))))
           :formatter activities-list--format-time))
       :objects-function (lambda ()
                           (map-values activities-activities))
       :sort-by '((2 . descend) (0 . descend))
       :actions `("q" (lambda (&rest _) (bury-buffer))
                  "n" (lambda (&rest _) (forward-line 1))
                  "p" (lambda (&rest _) (forward-line -1))
                  "RET" ,(activities-list-command activities-resume)
                  "k" ,(activities-list-command activities-kill)
                  "s" ,(activities-list-command activities-suspend)
                  "D" ,(activities-list-command activities-discard)))
      (pop-to-buffer (current-buffer)))))