Function: activity--serialize

activity--serialize is a byte-compiled function defined in activities.el.

Signature

(activity--serialize ARG &rest ARGS)

Implementations

(activity--serialize (BUFFER buffer)) in `activities.el'.

Return `activities-buffer' struct for BUFFER.

Source Code

;; Defined in ~/.emacs.d/elpa/activities-0.7.2/activities.el
(cl-defmethod activity--serialize ((buffer buffer))
  "Return `activities-buffer' struct for BUFFER."
  (with-current-buffer buffer
    (make-activities-buffer
     :bookmark (condition-case err
                   (bookmark-make-record)
                 (error
                  (pcase (error-message-string err)
                    ("Buffer not visiting a file or directory")
                    (_ (when activities-bookmark-warnings
                         (message (format "Activities: Error while making bookmark for buffer %S: %%S" buffer) err))))
                  nil))
     :filename (buffer-file-name buffer)
     :name (buffer-name buffer)
     ;; TODO: Handle indirect buffers, narrowing.
     :etc `((indirectp . ,(not (not (buffer-base-buffer buffer))))
            (narrowedp . ,(buffer-narrowed-p)))
     :local-variables
     (when activities-buffer-local-variables
       (cl-loop
        for variable in activities-buffer-local-variables
        when (buffer-local-boundp variable (current-buffer))
        collect (cons variable
                      (buffer-local-value variable (current-buffer))))))))