Function: article-fill-long-lines

article-fill-long-lines is an interactive and byte-compiled function defined in gnus-art.el.gz.

Signature

(article-fill-long-lines &optional WIDTH)

Documentation

Fill lines that are wider than the window width or fill-column.

If WIDTH (interactively, the numeric prefix), use that as the fill width.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
(defun article-fill-long-lines (&optional width)
  "Fill lines that are wider than the window width or `fill-column'.
If WIDTH (interactively, the numeric prefix), use that as the
fill width."
  (interactive "P" gnus-article-mode)
  (save-excursion
    (let* ((inhibit-read-only t)
	   (window-width (window-width (get-buffer-window (current-buffer))))
	   (width (if width
		      (prefix-numeric-value width)
		    (min fill-column window-width))))
      (save-restriction
	(article-goto-body)
	(let ((adaptive-fill-mode nil)) ;Why?  -sm
	  (while (not (eobp))
	    (end-of-line)
	    (when (>= (current-column) width)
	      (narrow-to-region (min (1+ (point)) (point-max))
                                (line-beginning-position))
              (let ((goback (point-marker))
		    (fill-column width))
                (fill-paragraph nil)
                (goto-char (marker-position goback)))
	      (widen))
	    (forward-line 1)))))))