Function: backtrace-expand-ellipses

backtrace-expand-ellipses is an interactive and byte-compiled function defined in backtrace.el.gz.

Signature

(backtrace-expand-ellipses &optional NO-LIMIT)

Documentation

Expand display of all "..."s in the backtrace frame at point.

Each ellipsis will be limited to backtrace-line-length characters in its expansion. With optional prefix argument NO-LIMIT, do not limit the number of characters. Note that with or without the argument, using this command can result in very long lines and very poor display performance. If this happens and is a problem, use g (revert-buffer) to return to the initial state of the Backtrace buffer.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/backtrace.el.gz
(defun backtrace-expand-ellipses (&optional no-limit)
  "Expand display of all \"...\"s in the backtrace frame at point.
\\<backtrace-mode-map>
Each ellipsis will be limited to `backtrace-line-length'
characters in its expansion.  With optional prefix argument
NO-LIMIT, do not limit the number of characters.  Note that with
or without the argument, using this command can result in very
long lines and very poor display performance.  If this happens
and is a problem, use `\\[revert-buffer]' to return to the
initial state of the Backtrace buffer."
  (interactive "P")
  (save-excursion
    (let ((start (backtrace-get-frame-start))
          (end (backtrace-get-frame-end))
          (backtrace-line-length (unless no-limit backtrace-line-length)))
      (goto-char end)
      (while (> (point) start)
        (let ((next (previous-single-property-change (point) 'cl-print-ellipsis
                                                     nil start)))
          (when (get-text-property (point) 'cl-print-ellipsis)
            (push-button (point)))
          (goto-char next))))))