Function: batch-update-autoloads

batch-update-autoloads is a byte-compiled function defined in autoload.el.gz.

Signature

(batch-update-autoloads)

Documentation

Update loaddefs.el autoloads in batch mode.

Calls update-directory-autoloads on the command line arguments. Definitions are written to generated-autoload-file (which should be non-nil).

Source Code

;; Defined in /usr/src/emacs/lisp/obsolete/autoload.el.gz
;;;###autoload
(defun batch-update-autoloads ()
  "Update loaddefs.el autoloads in batch mode.
Calls `update-directory-autoloads' on the command line arguments.
Definitions are written to `generated-autoload-file' (which
should be non-nil)."
  ;; For use during the Emacs build process only.
  ;; Exclude those files that are preloaded on ALL platforms.
  ;; These are the ones in loadup.el where "(load" is at the start
  ;; of the line (crude, but it works).
  (unless autoload-excludes
    (let ((default-directory (file-name-directory generated-autoload-file))
	  file)
      (when (file-readable-p "loadup.el")
	(with-temp-buffer
	  (insert-file-contents "loadup.el")
	  (while (re-search-forward "^(load \"\\([^\"]+\\)\"" nil t)
	    (setq file (match-string 1))
	    (or (string-match "\\.el\\'" file)
		(setq file (format "%s.el" file)))
	    (or (string-match "\\`site-" file)
		(push (expand-file-name file) autoload-excludes)))))))
  (let ((args command-line-args-left))
    (batch-update-autoloads--summary args)
    (setq command-line-args-left nil)
    (with-suppressed-warnings ((obsolete make-directory-autoloads))
      (make-directory-autoloads args generated-autoload-file))))