Function: browse-url-qutebrowser-send

browse-url-qutebrowser-send is a byte-compiled function defined in browse-url.el.gz.

Signature

(browse-url-qutebrowser-send CMD)

Documentation

Send CMD to Qutebrowser via IPC.

Source Code

;; Defined in /usr/src/emacs/lisp/net/browse-url.el.gz
(defun browse-url-qutebrowser-send (cmd)
  "Send CMD to Qutebrowser via IPC."
  (let* ((dir (xdg-runtime-dir))
         (sock (and dir (expand-file-name
                         (format "qutebrowser/ipc-%s" (md5 (user-login-name)))
                         dir))))
    (unless (file-exists-p sock)
      (error "No Qutebrowser IPC socket found"))
    (let ((proc
           (make-network-process
            :name "qutebrowser"
            :family 'local
            :service sock
            :coding 'utf-8)))
      (unwind-protect
          (process-send-string
           proc
           (concat
            (json-serialize `( :args [,cmd]
                               :target_arg :null
                               :protocol_version 1))
            "\n"))
        (delete-process proc)))))