Function: c-font-lock-cpp-messages

c-font-lock-cpp-messages is a byte-compiled function defined in cc-fonts.el.gz.

Signature

(c-font-lock-cpp-messages LIMIT)

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/cc-fonts.el.gz
(defun c-font-lock-cpp-messages (limit)
  ;; Font lock #error and #warning messages between point and LIMIT.
  ;; Always return nil to prevent a further call to this function.
  ;; The position of point at the end of this function is random.
  (while
      (and (< (point) limit)
	   (re-search-forward c-cpp-messages-re limit t))
    (let ((beg (match-beginning c-cpp-message-match-no))
	  (end (match-end c-cpp-message-match-no)))
      ;; Don't use c-put-font-lock-string-face here, since in XEmacs that
      ;; would fail to fontify the first and last characters - We don't have
      ;; any string delimiters in this construction.
      (c-put-font-lock-face beg end 'font-lock-string-face)
      ;; We replace '(1) (punctuation) syntax-table text properties on ' by
      ;; '(3) (symbol), so that these characters won't later get the warning
      ;; face.
      (goto-char beg)
      (while (and
	      (< (point) end)
	      (c-search-forward-char-property-with-value-on-char
	       'syntax-table '(1) ?\' end))
	(c-put-char-property ;; -trim-caches
			    (1- (point)) 'syntax-table '(3)))
      (goto-char end)))
  nil)