Function: c-font-lock-enum-tail

c-font-lock-enum-tail is a byte-compiled function defined in cc-fonts.el.gz.

Signature

(c-font-lock-enum-tail LIMIT)

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/cc-fonts.el.gz
(defun c-font-lock-enum-tail (limit)
  ;; Fontify an enum's identifiers when POINT is within the enum's brace
  ;; block.
  ;;
  ;; This function will be called from font-lock for a region bounded by POINT
  ;; and LIMIT, as though it were to identify a keyword for
  ;; font-lock-keyword-face.  It always returns NIL to inhibit this and
  ;; prevent a repeat invocation.  See elisp/lispref page "Search-based
  ;; Fontification".
  ;;
  ;; Note that this function won't attempt to fontify beyond the end of the
  ;; current enum block, if any.
  (c-skip-comments-and-strings limit)
  (when (< (point) limit)
    (let* ((paren-state (c-parse-state))
	   (encl-pos (c-most-enclosing-brace paren-state)))
      (when (and
	     encl-pos
	     (eq (char-after encl-pos) ?\{)
	     (c-at-enum-brace encl-pos))
	(c-syntactic-skip-backward "^{," nil t)
	(c-put-char-property (1- (point)) 'c-type 'c-decl-id-start)

	(c-forward-syntactic-ws)
	(c-font-lock-declarators limit t nil t))))
  nil)