Function: c-set-doc-comment-re-element

c-set-doc-comment-re-element is a macro defined in cc-fonts.el.gz.

Signature

(c-set-doc-comment-re-element SUFFIX)

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/cc-fonts.el.gz
;; A list of characters, each being a last character of a doc comment marker,
;; e.g. the ! from pike autodoc's "//!".

(defmacro c-set-doc-comment-re-element (suffix)
  ;; Set the variable `c-doc-line-join-re' to a buffer local value suitable
  ;; for the current doc comment style, or kill the local value.
  (declare (debug t))
  (let ((var (intern (concat "c-doc" suffix))))
    `(let* ((styles (c-get-doc-comment-style))
	    elts)
       (when (atom styles)
	 (setq styles (list styles)))
       (setq elts
	     (mapcar (lambda (style)
		       (let ((sym
			      (intern-soft
			       (concat (symbol-name style) ,suffix))))
			 (and sym
			      (boundp sym)
			      (symbol-value sym))))
		     styles))
       (setq elts (delq nil elts))
       (setq elts (and elts
		       (concat "\\("
			       (mapconcat #'identity elts "\\|")
			       "\\)")))
       (if elts
	   (set (make-local-variable ',var) elts)
	 (kill-local-variable ',var)))))