Function: cal-tex-insert-days

cal-tex-insert-days is a byte-compiled function defined in cal-tex.el.gz.

Signature

(cal-tex-insert-days MONTH YEAR DIARY-LIST HOLIDAYS DAY-FORMAT)

Documentation

Insert LaTeX commands for a range of days in monthly calendars.

LaTeX commands are inserted for the days of the MONTH in YEAR. Diary entries on DIARY-LIST are included. Holidays on HOLIDAYS are included. Each day is formatted using format DAY-FORMAT.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-tex.el.gz
(defun cal-tex-insert-days (month year diary-list holidays day-format)
  "Insert LaTeX commands for a range of days in monthly calendars.
LaTeX commands are inserted for the days of the MONTH in YEAR.
Diary entries on DIARY-LIST are included.  Holidays on HOLIDAYS
are included.  Each day is formatted using format DAY-FORMAT."
  (with-suppressed-warnings ((lexical date))
    (defvar date))                      ;For `cal-tex-daily-string'.
  (let ((blank-days                     ; at start of month
         (mod
          (- (calendar-day-of-week (list month 1 year))
             calendar-week-start-day)
          7))
        (last (calendar-last-day-of-month month year))
        date j)
    (dotimes (i last)
      (setq j (1+ i)                    ; 1-last, incl
            date (list month j year))
      (when (memq (calendar-day-of-week date) cal-tex-which-days)
        (insert (format day-format (cal-tex-month-name month) j))
        (cal-tex-arg (cal-tex-latexify-list diary-list date))
        (cal-tex-arg (cal-tex-latexify-list holidays date))
        (cal-tex-arg (eval cal-tex-daily-string t))
        (cal-tex-arg)
        (cal-tex-comment))
      (when (and (zerop (mod (+ j blank-days) 7))
                 (/= j last))
        (cal-tex-hfill)
        (cal-tex-nl)))))