Function: calc-do-embedded-activate

calc-do-embedded-activate is an autoloaded and byte-compiled function defined in calc-embed.el.gz.

Signature

(calc-do-embedded-activate EMBED-ARG CBUF)

Source Code

;; Defined in /usr/src/emacs/lisp/calc/calc-embed.el.gz
;;;###autoload
(defun calc-do-embedded-activate (embed-arg cbuf)
  (let ((calc-embed-arg embed-arg))
  (calc-plain-buffer-only)
  (if calc-embed-arg
      (calc-embedded-forget))
  (calc-find-globals)
  (if (< (prefix-numeric-value calc-embed-arg) 0)
      (message "Deactivating %s for Calc Embedded mode" (buffer-name))
    (message "Activating %s for Calc Embedded mode..." (buffer-name))
    (save-excursion
      (let* ((active (assq (current-buffer) calc-embedded-active))
	     (info active)
	     (pat " := \\| \\\\gets \\| => \\| \\\\evalto "))
	(if calc-embedded-announce-formula
	    (setq pat (format "%s\\|\\(%s\\)"
			      pat calc-embedded-announce-formula)))
	(while (setq info (cdr info))
	  (or (equal (buffer-substring (aref (car info) 2) (aref (car info) 3))
		     (aref (car info) 6))
	      (setcdr active (delq (car info) (cdr active)))))
	(goto-char (point-min))
	(while (re-search-forward pat nil t)
;;;	  (if (looking-at calc-embedded-open-formula)
;;;	      (goto-char (match-end 1)))
	  (setq info (calc-embedded-make-info (point) cbuf nil))
	  (or (eq (car-safe (aref info 8)) 'error)
	      (goto-char (aref info 5))))))
    (message "Activating %s for Calc Embedded mode...done" (buffer-name)))
  (calc-embedded-active-state t)))