Function: calcFunc-arg

calcFunc-arg is an autoloaded and byte-compiled function defined in calc-cplx.el.gz.

Signature

(calcFunc-arg A)

Source Code

;; Defined in /usr/src/emacs/lisp/calc/calc-cplx.el.gz
;;; Compute the complex argument of A.  [F N] [Public]
(defun calcFunc-arg (a)
  (cond ((Math-anglep a)
	 (if (math-negp a) (math-half-circle nil) 0))
	((eq (car-safe a) 'cplx)
	 (calcFunc-arctan2 (nth 2 a) (nth 1 a)))
	((eq (car-safe a) 'polar)
	 (nth 2 a))
	((eq (car a) 'vec)
	 (math-map-vec 'calcFunc-arg a))
	((and (equal a '(var i var-i))
	      (math-imaginary-i))
	 (math-quarter-circle t))
	((and (equal a '(neg (var i var-i)))
	      (math-imaginary-i))
	 (math-neg (math-quarter-circle t)))
	((let ((signs (math-possible-signs a)))
	   (or (and (memq signs '(2 4 6)) 0)
	       (and (eq signs 1) (math-half-circle nil)))))
	((math-infinitep a)
	 (if (or (equal a '(var uinf var-uinf))
		 (equal a '(var nan var-nan)))
	     '(var nan var-nan)
	   (calcFunc-arg (math-infinite-dir a))))
	(t (calc-record-why 'numvecp a)
	   (list 'calcFunc-arg a))))