Function: calendar-julian-goto-date

calendar-julian-goto-date is an autoloaded, interactive and byte-compiled function defined in cal-julian.el.gz.

Signature

(calendar-julian-goto-date DATE &optional NOECHO)

Documentation

Move cursor to Julian DATE; echo Julian date unless NOECHO is non-nil.

View in manual

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-julian.el.gz
;;;###cal-autoload
(defun calendar-julian-goto-date (date &optional noecho)
  "Move cursor to Julian DATE; echo Julian date unless NOECHO is non-nil."
  (interactive
   (let* ((today (calendar-current-date))
          (year (calendar-read-sexp
                 "Julian calendar year (>0)"
                 (lambda (x) (> x 0))
                 (calendar-extract-year
                  (calendar-julian-from-absolute
                   (calendar-absolute-from-gregorian
                    today)))))
          (month-array calendar-month-name-array)
          (completion-ignore-case t)
          (month (cdr (assoc-string
                       (completing-read
                        "Julian calendar month name: "
                        (mapcar 'list (append month-array nil))
                        nil t)
                       (calendar-make-alist month-array 1) t)))
          (last
           (if (and (zerop (% year 4)) (= month 2))
               29
             (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
          (day (calendar-read-sexp
                "Julian calendar day (%d-%d)"
                (lambda (x)
                  (and (< (if (and (= year 1) (= month 1)) 2 0) x)
                       (<= x last)))
                (if (and (= year 1) (= month 1)) 3 1)
                (if (and (= year 1) (= month 1)) 3 1) last)))
     (list (list month day year))))
  (calendar-goto-date (calendar-gregorian-from-absolute
                       (calendar-julian-to-absolute date)))
  (or noecho (calendar-julian-print-date)))