Function: change-log-next-error

change-log-next-error is an interactive and byte-compiled function defined in add-log.el.gz.

Signature

(change-log-next-error &optional ARGP RESET)

Documentation

Move to the Nth (default 1) next match in a ChangeLog buffer.

Compatibility function for C-x ` (next-error) invocations.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/vc/add-log.el.gz
(defun change-log-next-error (&optional argp reset)
  "Move to the Nth (default 1) next match in a ChangeLog buffer.
Compatibility function for \\[next-error] invocations."
  (interactive "p")
  (let* ((argp (or argp 0))
	 (count (abs argp))		; how many cycles
	 (down (< argp 0))		; are we going down? (is argp negative?)
	 (up (not down))
	 (search-function (if up #'re-search-forward #'re-search-backward)))

    ;; set the starting position
    (goto-char (cond (reset (point-min))
		     (down (line-beginning-position))
		     (up (line-end-position))
		     ((point))))

    (funcall search-function change-log-file-names-re nil t count))

  (beginning-of-line)
  ;; if we found a place to visit...
  (when (looking-at change-log-file-names-re)
    (let (change-log-find-window)
      (change-log-goto-source-internal)
      (when change-log-find-window
	;; Select window displaying source file.
	(select-window change-log-find-window)))))