Function: cider-info-request

cider-info-request is a byte-compiled function defined in cider-client.el.

Signature

(cider-info-request &key SYM CLASS MEMBER CONTEXT)

Documentation

Send "info" op with parameters SYM or CLASS and MEMBER, honor CONTEXT.

This is the keyword-argument form; cider-sync-request:info is the legacy positional shim retained for backward compatibility.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260807.1133/cider-client.el
(cl-defun cider-info-request (&key sym class member context)
  "Send \"info\" op with parameters SYM or CLASS and MEMBER, honor CONTEXT.

This is the keyword-argument form; `cider-sync-request:info' is the legacy
positional shim retained for backward compatibility."
  (let* ((req
          `("op" "cider/info"
            "ns" ,(cider-current-ns)
            ,@(when sym `("sym" ,sym))
            ,@(when class `("class" ,class))
            ,@(when member `("member" ,member))
            ,@(when context `("context" ,context))
            ,@(when cider-download-java-sources `("download-sources-jar" "1"))))
         (callback
          (lambda (resp)
            (let ((status (nrepl-dict-get resp "status"))
                  (coords (nrepl-dict-get resp "coords")))
              (when (member "download-sources-jar" status)
                (message "Local source not found, downloading Java sources for artifact %s/%s %s..."
                         (nrepl-dict-get coords "group")
                         (nrepl-dict-get coords "artifact")
                         (nrepl-dict-get coords "version"))))))
         (var-info
          (cider-nrepl-sync-request req :connection (cider-current-repl) :callback callback)))
    (if (member "no-info" (nrepl-dict-get var-info "status"))
        nil
      var-info)))