Function: completion--insert-one-column

completion--insert-one-column is a byte-compiled function defined in minibuffer.el.gz.

Signature

(completion--insert-one-column STRINGS GROUP-FUN LENGTH WWIDTH COLWIDTH COLUMNS LINES &optional LAST-TITLE)

Source Code

;; Defined in /usr/src/emacs/lisp/minibuffer.el.gz
(defun completion--insert-one-column ( strings group-fun length wwidth colwidth
                                       columns lines &optional last-title)
  (let ((last-string nil)
        str)
    (while strings
      (setq str (pop strings))
      (unless (equal last-string str) ; Remove (consecutive) duplicates.
	(setq last-string str)
        (when group-fun
          (let ((title (funcall group-fun (if (consp str) (car str) str) nil)))
            (unless (equal title last-title)
              (setq last-title title)
              (when title
                (insert (format completions-group-format title) "\n")))))
        (completion--insert str group-fun)
        (insert "\n")
        (when (and lines (> (line-number-at-pos) lines))
          (throw 'completions-truncated
                 (lambda ()
                   (completion--insert-one-column
                    strings group-fun length wwidth colwidth columns nil
                    last-title))))))
    (delete-char -1)))