Function: consult-register-store

consult-register-store is an autoloaded, interactive and byte-compiled function defined in consult-register.el.

Signature

(consult-register-store ARG)

Documentation

Store register dependent on current context, showing an action menu.

With an active region, store/append/prepend the contents, optionally deleting the region when a prefix ARG is given. With a numeric prefix ARG, store or add the number. Otherwise store point, frameset, window or kmacro.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/consult-20260805.1130/consult-register.el
;;;###autoload
(defun consult-register-store (arg)
  "Store register dependent on current context, showing an action menu.

With an active region, store/append/prepend the contents, optionally
deleting the region when a prefix ARG is given.  With a numeric prefix
ARG, store or add the number.  Otherwise store point, frameset, window or
kmacro."
  (interactive "P")
  (consult-register--action
   (cond
    ((use-region-p)
     (let ((beg (region-beginning))
           (end (region-end)))
       `("Region"
         (?c "copy" "Copy region to register: " ,(lambda (r) (copy-to-register r beg end arg t)))
         (?a "append" "Append region to register: " ,(lambda (r) (append-to-register r beg end arg)))
         (?p "prepend" "Prepend region to register: " ,(lambda (r) (prepend-to-register r beg end arg))))))
    ((numberp arg)
     `(,(format "Number %s" arg)
       (?s "store" ,(format "Store %s in register: " arg) ,(lambda (r) (number-to-register arg r)))
       (?a "add" ,(format "Add %s to register: " arg) ,(lambda (r) (increment-register arg r)))))
    (t
     `("Store"
       (?p "point" "Point to register: " ,#'point-to-register)
       ,@(when-let* ((file (or buffer-file-name default-directory)))
          `((?f "file" "File to register: " ,(lambda (r) (set-register r `(file . ,file))))))
       (?b "buffer" "Buffer to register: " ,(lambda (r) (set-register r `(buffer . ,(buffer-name)))))
       (?t "frameset" "Frameset to register: " ,#'frameset-to-register)
       (?w "window" "Window to register: " ,#'window-configuration-to-register)
       ,@(and last-kbd-macro `((?k "kmacro" "Kmacro to register: " ,#'kmacro-to-register))))))))