Function: corfu-info--restore-on-next-command

corfu-info--restore-on-next-command is a byte-compiled function defined in corfu-info.el.

Signature

(corfu-info--restore-on-next-command)

Documentation

Restore window configuration before next command.

Source Code

;; Defined in ~/.emacs.d/elpa/corfu-20260813.950/corfu-info.el
(defun corfu-info--restore-on-next-command ()
  "Restore window configuration before next command."
  (let ((config (current-window-configuration))
        (other other-window-scroll-buffer)
        (restore (make-symbol "corfu--restore")))
    (fset restore
          (lambda ()
            (setq other-window-scroll-buffer other)
            (unless (memq this-command '(scroll-other-window scroll-other-window-down))
              (when (memq this-command '(corfu-quit corfu-reset))
                (setq this-command #'ignore))
              (remove-hook 'pre-command-hook restore)
              (set-window-configuration config))))
    (add-hook 'pre-command-hook restore)))