Function: custom-fix-face-spec

custom-fix-face-spec is a byte-compiled function defined in custom.el.gz.

Signature

(custom-fix-face-spec SPEC)

Documentation

Convert face SPEC, replacing obsolete :bold and :italic attributes.

Also change :reverse-video to :inverse-video.

Source Code

;; Defined in /usr/src/emacs/lisp/custom.el.gz
(defun custom-fix-face-spec (spec)
  "Convert face SPEC, replacing obsolete :bold and :italic attributes.
Also change :reverse-video to :inverse-video."
  (when (listp spec)
    (if (or (memq :bold spec)
	    (memq :italic spec)
	    (memq :reverse-video spec))
	(let (result)
	  (while spec
	    (let ((key (car spec))
		  (val (car (cdr spec))))
	      (cond ((eq key :italic)
		     (push :slant result)
		     (push (if val 'italic 'normal) result))
		    ((eq key :bold)
		     (push :weight result)
		     (push (if val 'bold 'normal) result))
		    ((eq key :reverse-video)
		     (push :inverse-video result)
		     (push val result))
		    (t
		     (push key result)
		     (push val result))))
	    (setq spec (cddr spec)))
	  (nreverse result))
      spec)))