Function: describe-theme-1

describe-theme-1 is a byte-compiled function defined in cus-theme.el.gz.

Signature

(describe-theme-1 THEME)

Source Code

;; Defined in /usr/src/emacs/lisp/cus-theme.el.gz
(defun describe-theme-1 (theme)
  (prin1 theme)
  (princ " is a custom theme")
  (let ((fn (locate-file (concat (symbol-name theme) "-theme.el")
			 (custom-theme--load-path)
			 '("" "c")))
	doc)
    (when fn
      (princ (substitute-command-keys " in `"))
      (help-insert-xref-button (file-name-nondirectory fn)
			       'help-theme-def fn)
      (princ (substitute-quotes "'")))
    (princ ".\n")
    (if (custom-theme-p theme)
	(progn
	  (if (custom-theme-enabled-p theme)
	      (princ "It is loaded and enabled.")
	    (princ "It is loaded but disabled."))
	  (setq doc (get theme 'theme-documentation)))
      (princ "It is not loaded.")
      ;; Attempt to grab the theme documentation from file.
      (when fn
	(setq doc (describe-theme-from-file theme fn))))
    (princ "\n\nDocumentation:\n")
    (princ (if (stringp doc)
	       (substitute-command-keys doc)
	     "No documentation available.")))
  (princ "\n\nYou can ")
  (help-insert-xref-button "customize" 'help-theme-edit theme)
  (princ " this theme."))