Function: diary-display-no-entries

diary-display-no-entries is a byte-compiled function defined in diary-lib.el.gz.

Signature

(diary-display-no-entries)

Documentation

Common subroutine of diary-simple-display and diary-fancy-display.

Handles the case where there are no diary entries. Returns a cons (NOENTRIES . HOLIDAY-STRING).

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/diary-lib.el.gz
(defun diary-display-no-entries ()
  "Common subroutine of `diary-simple-display' and `diary-fancy-display'.
Handles the case where there are no diary entries.
Returns a cons (NOENTRIES . HOLIDAY-STRING)."
    (let* ((holiday-list (if diary-show-holidays-flag
                             (calendar-check-holidays original-date)))
           (hol-string (format "%s%s%s"
                               diary--date-string
                               (if holiday-list ": " "")
                               (mapconcat #'identity holiday-list "; ")))
           (msg (format "No diary entries for %s" hol-string))
           ;; Empty list, or single item with no text.
           ;; FIXME multiple items with no text?
           (noentries (or (not diary-entries-list)
                          (and (not (cdr diary-entries-list))
                               (string-equal "" (cadr
                                                 (car diary-entries-list)))))))
      ;; Inconsistency: whether or not the holidays are displayed in a
      ;; separate buffer depends on if there are diary entries.
      (when noentries
        (if (or (< (length msg) (frame-width))
                (not holiday-list))
            (message "%s" msg)
          ;; holiday-list which is too wide for a message gets a buffer.
          (calendar-in-read-only-buffer holiday-buffer
            (calendar-set-mode-line (format "Holidays for %s"
                                            diary--date-string))
            (insert (mapconcat #'identity holiday-list "\n")))
          (message "No diary entries for %s" diary--date-string)))
      (cons noentries hol-string)))