Function: diary-sexp-entry

diary-sexp-entry is a byte-compiled function defined in diary-lib.el.gz.

Signature

(diary-sexp-entry SEXP ENTRY DATE)

Documentation

Process a SEXP diary ENTRY for DATE.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/diary-lib.el.gz
(defun diary-sexp-entry (sexp entry date)
  "Process a SEXP diary ENTRY for DATE."
  (let ((result
         (calendar-dlet ((date date)
                          (entry entry))
           (if calendar-debug-sexp
               (let ((debug-on-error t))
                 (eval (car (read-from-string sexp))))
             (condition-case err
                 (eval (car (read-from-string sexp)))
               (error
                (display-warning
                 'diary
                 (format "Bad diary sexp at line %d in %s:\n%s\n\
Error: %S\n"
                         (count-lines (point-min) (point))
                         diary-file sexp err)
                 :error)
                nil))))))
    (cond ((stringp result) result)
          ((and (consp result)
                (stringp (cdr result)))
           result)
          (result entry)
          (t nil))))