Function: dired-create-files-non-directory

dired-create-files-non-directory is a byte-compiled function defined in dired-aux.el.gz.

Signature

(dired-create-files-non-directory FILE-CREATOR BASENAME-CONSTRUCTOR OPERATION ARG)

Source Code

;; Defined in /usr/src/emacs/lisp/dired-aux.el.gz
(defun dired-create-files-non-directory
    (file-creator basename-constructor operation arg)
  ;; Perform FILE-CREATOR on the non-directory part of marked files
  ;; using function BASENAME-CONSTRUCTOR, with query for each file.
  ;; OPERATION like in dired-create-files, ARG as in dired-get-marked-files.
  (let (rename-non-directory-query)
    (dired-create-files
     file-creator
     operation
     (dired-get-marked-files nil arg)
     (lambda (from)
       (let ((to (concat (file-name-directory from)
			 (funcall basename-constructor
				  (file-name-nondirectory from)))))
         (and (let ((help-form (format-message
                                (substitute-command-keys "\
Type \\`SPC' or \\`y' to %s one file, \\`DEL' or \\`n' to skip to next,
\\`!' to %s all remaining matches with no more questions.")
                                (downcase operation)
                                (downcase operation))))
		(dired-query 'rename-non-directory-query
			     (concat operation " `%s' to `%s'")
			     (dired-make-relative from)
			     (dired-make-relative to)))
	      to)))
     dired-keep-marker-rename)))