Function: dired-mark-read-string

dired-mark-read-string is a byte-compiled function defined in dired-aux.el.gz.

Signature

(dired-mark-read-string PROMPT INITIAL OP-SYMBOL ARG FILES &optional DEFAULT-VALUE COLLECTION)

Documentation

Read args for a Dired marked-files command, prompting with PROMPT.

Return the user input (a string).

INITIAL, if non-nil, is the initial minibuffer input. OP-SYMBOL is an operation symbol (see dired-no-confirm). ARG is normally the prefix argument for the calling command; it is passed as the first argument to dired-mark-prompt. FILES should be a list of marked files' names.

Optional arg DEFAULT-VALUE is a default value or list of default values, passed as the seventh arg to completing-read.

Optional arg COLLECTION is a collection of possible completions, passed as the second arg to completing-read.

Source Code

;; Defined in /usr/src/emacs/lisp/dired-aux.el.gz
(defun dired-mark-read-string (prompt initial op-symbol arg files
                                      &optional default-value collection)
  "Read args for a Dired marked-files command, prompting with PROMPT.
Return the user input (a string).

INITIAL, if non-nil, is the initial minibuffer input.
OP-SYMBOL is an operation symbol (see `dired-no-confirm').
ARG is normally the prefix argument for the calling command;
it is passed as the first argument to `dired-mark-prompt'.
FILES should be a list of marked files' names.

Optional arg DEFAULT-VALUE is a default value or list of default
values, passed as the seventh arg to `completing-read'.

Optional arg COLLECTION is a collection of possible completions,
passed as the second arg to `completing-read'."
  (apply #'dired-mark-pop-up
         nil op-symbol files
         (if (eq op-symbol 'touch) 'read-from-minibuffer 'completing-read)
         (format prompt (dired-mark-prompt arg files))
         (if (eq op-symbol 'touch)
             `(,initial nil nil nil ,default-value)
           `(,collection nil nil ,initial nil ,default-value nil))))