Function: doc-view--parse-djvu-outline

doc-view--parse-djvu-outline is a byte-compiled function defined in doc-view.el.gz.

Signature

(doc-view--parse-djvu-outline BOOKMARK &optional LEVEL)

Documentation

Return a list describing the djvu outline from BOOKMARK.

Optional argument LEVEL is the current heading level, which defaults to 1.

Source Code

;; Defined in /usr/src/emacs/lisp/doc-view.el.gz
(defun doc-view--parse-djvu-outline (bookmark &optional level)
  "Return a list describing the djvu outline from BOOKMARK.
Optional argument LEVEL is the current heading level, which defaults to 1."
  (unless level (setq level 1))
  (let ((res))
    (unless (eq (car bookmark) 'bookmarks)
      (user-error "Unknown outline type: %S" (car bookmark)))
    (pcase-dolist (`(,title ,page . ,rest) (cdr bookmark))
      (push `((level . ,level)
              (title . ,title)
              (page . ,(string-to-number (string-remove-prefix "#" page))))
            res)
      (when (and rest (listp (car rest)))
        (setq res (append
                   (doc-view--parse-djvu-outline
                    (cons 'bookmarks rest)
                    (+ level 1))
                   res))))
    res))