Function: ecomplete-completion-table

ecomplete-completion-table is a byte-compiled function defined in ecomplete.el.gz.

Signature

(ecomplete-completion-table TYPE)

Documentation

Return a completion-table suitable for TYPE.

Source Code

;; Defined in /usr/src/emacs/lisp/ecomplete.el.gz
(defun ecomplete-completion-table (type)
  "Return a completion-table suitable for TYPE."
  (lambda (string pred action)
    (pcase action
      (`(boundaries . ,_) nil)
      ('metadata `(metadata (category . ecomplete)
                            (display-sort-function . ,#'identity)
                            (cycle-sort-function . ,#'identity)))
      (_
       (let* ((elems (cdr (assq type ecomplete-database)))
	      (candidates
	       (mapcar (lambda (x) (nth 2 x))
                       (sort
                        (cl-loop for x in elems
                                 when (string-prefix-p string (nth 3 x)
                                                       completion-ignore-case)
                                 collect (cdr x))
                        ecomplete-sort-predicate))))
         (complete-with-action action candidates string pred))))))