Function: ede-add-file

ede-add-file is an interactive and byte-compiled function defined in ede.el.gz.

Signature

(ede-add-file TARGET)

Documentation

Add the current buffer to a TARGET in the current project.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/cedet/ede.el.gz
(defun ede-add-file (target)
  "Add the current buffer to a TARGET in the current project."
  (interactive (list
		(let ((ede-object (ede-current-project)))
		  (ede-invoke-method 'project-interactive-select-target
				     "Target: "))))
  (when (stringp target)
    (let* ((proj (ede-current-project))
	   (ob (object-assoc-list 'name (oref proj targets))))
      (setq target (cdr (assoc target ob)))))

  (when (not target)
    (error "Could not find specified target %S" target))

  (project-add-file target (buffer-file-name))
  (setq ede-object nil)

  ;; Setup buffer local variables.
  (ede-initialize-state-current-buffer)

  (when (not ede-object)
    (error "Can't add %s to target %s: Wrong file type"
	   (file-name-nondirectory (buffer-file-name))
	   (eieio-object-name target)))
  (ede-apply-target-options))