Function: ediff-show-diff-output

ediff-show-diff-output is an interactive and byte-compiled function defined in ediff-util.el.gz.

Signature

(ediff-show-diff-output ARG)

Documentation

With prefix argument ARG, show plain diff output.

Without an argument, save the customized diff argument, if available
(and plain output, if customized output was not generated).

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/vc/ediff-util.el.gz
(defun ediff-show-diff-output (arg)
  "With prefix argument ARG, show plain diff output.
Without an argument, save the customized diff argument, if available
(and plain output, if customized output was not generated)."
  (interactive "P")
  (ediff-barf-if-not-control-buffer)
  (ediff-compute-custom-diffs-maybe)
  (save-excursion
    (ediff-skip-unsuitable-frames ' ok-unsplittable))
  (let ((buf (cond ((and arg (ediff-buffer-live-p ediff-diff-buffer))
		    ediff-diff-buffer)
		   ((and (ediff-buffer-live-p ediff-custom-diff-buffer)
                         ;; We may not have gotten a custom output if
                         ;; we're working on unsaved buffers.
                         (> (buffer-size ediff-custom-diff-buffer) 0))
		    ediff-custom-diff-buffer)
		   ((ediff-buffer-live-p ediff-diff-buffer)
		    ediff-diff-buffer)
		   (t
		    (beep)
		    (message "Output from `diff' not found")
		    nil))))
    (if buf
	(progn
	  (ediff-with-current-buffer buf
	    (goto-char (point-min)))
	  (switch-to-buffer buf)
	  (raise-frame))))
  (if (frame-live-p ediff-control-frame)
      (ediff-reset-mouse ediff-control-frame))
  (if (window-live-p ediff-control-window)
      (select-window ediff-control-window)))